# C-shell environment variable definitions for the user 'mcidas'

# umask
umask 002

# Make sure that McINST_ROOT is defined
if ( ! $?McINST_ROOT ) then
  # echo McINST_ROOT not defined, setting it to $HOME
  setenv McINST_ROOT $HOME
endif

# MCHOME
if ( ! $?MCHOME ) then
  # echo MCHOME not defined, setting it to $McINST_ROOT
  setenv MCHOME $McINST_ROOT
endif

# MCDATA
if ( ! $?MCDATA ) then
  # echo MCDATA not defined, setting it to $MCHOME/workdata
  setenv MCDATA $MCHOME/workdata
endif

# McIDAS Version
if ( ! $?MCVER ) then
  # echo MCVER not defined, setting it to $MCVER/mcidas<version>
  setenv MCVER `cat $MCHOME/data/VERSION.TXT | sed "s/^\(....\).*/\1/"`
endif

# NOTE: conditional definition is only needed for C-shell users
if ( ! ${?MCPATH} ) then
  setenv MCPATH ${MCDATA}:$MCHOME/workdata:$MCHOME/data:$MCHOME/help
  setenv MCBIN    $MCHOME/bin
  setenv MCGUI    $MCHOME/bin
  setenv MCSRC    $MCHOME/mcidas$MCVER/src
  setenv MCUPDATE $MCHOME/mcidas$MCVER/update
  setenv MCTABLE_READ "${MCDATA}/MCTABLE.TXT;$MCHOME/data/ADDESITE.TXT"
  setenv MCTABLE_WRITE "$MCHOME/data/ADDESITE.TXT"
  setenv MCSTRETCH "EXP"
  setenv XCD_disp_file $MCDATA/DECOSTAT.DAT
  if ( ! ${?path} ) then
    set path=$MCGUI
  else
    set path=(${MCGUI} $path)
  endif
endif

# Limit ADDE transfers to compressed ones
setenv MCCOMPRESS GZIP

#
# Set compilation options based on VENDOR environment variable
#

if ( ! ${?VENDOR} ) then
  # echo VENDOR not defined, defaulting to '-vendor'
  setenv VENDOR -vendor
endif

# If VENDOR is defined to be '-g77' or '-gfortran', the settings are invariant by OS
if ( "$VENDOR" == "-g77" ) then
  # echo Setting -g77 compilation options...
  setenv CC       gcc
  setenv CPPFLAGS "-DNDEBUG -Df2cFortran"
  setenv CFLAGS   "-O"
  setenv CXX      ""
  setenv CXXCPP   ""
  setenv FC       g77
  setenv FFLAGS   "-O -Wuninitialized -fno-automatic -ff90-intrinsics-hide"
  setenv F90      ""

else if ( "$VENDOR" == "-gfortran" ) then
  # echo Setting -gfortran compilation options...
  setenv CC       gcc
  setenv CPPFLAGS "-DNDEBUG -Df2cFortran"
  setenv CFLAGS   "-O"
  setenv CXX      ""
  setenv CXXCPP   ""
  setenv FC       gfortran
  setenv FFLAGS   "-O -Wuninitialized -fno-automatic -fno-range-check"
  setenv F90      ""

else

  # VENDOR is '-vendor'
  set uname_s=`uname -s`
  switch ( $uname_s )
  
    case AIX:
      setenv CC       cc
      setenv C_COMP   cc
      setenv CPPFLAGS -DNDEBUG
      setenv CFLAGS   "-qcpluscmt"
      setenv CXX      ""
      setenv CXXCPP   ""
      setenv FC       f77
      setenv F_COMP   f77
      setenv FFLAGS   -O
      setenv F90      ""
      setenv INSTALL  cp
      breaksw
  
    case Darwin:
      setenv CC       gcc
      setenv C_COMP   gcc
      setenv CPPFLAGS "-Df2cFortran"
      setenv CFLAGS   "-O"
      setenv CXX      ""
      setenv CXXCPP   ""
      setenv FC       g77
      setenv F_COMP   g77
      setenv FFLAGS   "-O -Wuninitialized -fno-automatic -ff90-intrinsics-hide"
      setenv F90      ""
      setenv LDFLAGS '-flat_namespace -undefined suppress'
      breaksw
  
    case FreeBSD:
      setenv CC       gcc
      setenv CPPFLAGS "-DNDEBUG -Df2cFortran"
      setenv CFLAGS   "-O"
      setenv CXX      ""
      setenv CXXCPP   ""
      setenv FC       f77
      setenv FFLAGS   "-O -Wuninitialized -fno-automatic -ff90-intrinsics-hide"
      setenv F90      ""
      setenv EXPR_COMPAT 1
      breaksw
  
    case HP-UX:
      setenv CC       cc
      setenv CPPFLAGS "-D_HPUX_SOURCE -DNDEBUG"
      setenv CFLAGS   "-O -Ae"
      setenv CXX      ""
      setenv CXXCPP   ""
      setenv FC       f77
      setenv FFLAGS   "-O3 -w"
      setenv F90      ""
      setenv MCNSL    -lnsl
      breaksw
  
    case IRIX*:
      setenv CC       "cc"
      setenv C_COMP   "cc"
      setenv CPPFLAGS -DNDEBUG
      setenv CFLAGS   "-O -c99"
      setenv CXX      ""
      setenv CXXCPP   ""
      setenv FC       "f77"
      setenv F_COMP   "f77"
      setenv FFLAGS   -O
      setenv F90      ""
      breaksw
  
    case Linux:
      setenv CC       gcc
      setenv CPPFLAGS "-DNDEBUG -Df2cFortran"
      setenv CFLAGS   "-O"
      setenv CXX      ""
      setenv CXXCPP   ""
      setenv FC       gfortran
      setenv FFLAGS   "-O -Wuninitialized -fno-automatic -fno-range-check"
      setenv F90      ""
      breaksw

    case OSF1:
      setenv CC       cc
      setenv CPPFLAGS -DNDEBUG
      setenv CFLAGS   "-O"
      setenv CXX      ""
      setenv CXXCPP   ""
      setenv FC       f77
      setenv FFLAGS   -O
      setenv F90      ""
      breaksw
  
    case SunOS:
      if ( ! ${?XARCH} ) then
        setenv XARCH ""
      endif
      setenv CC        "cc $XARCH"
      setenv CCOMPILER "$CC"
      setenv CPPFLAGS  "-DNDEBUG $XARCH"
      setenv CFLAGS    "-O"
      setenv CXX       ""
      setenv CXXCPP    ""
      setenv FC        "f77 $XARCH"
      setenv FFLAGS    "-O -erroff=WDECL_LOCAL_NOTUSED"
      setenv F90       ""
      breaksw
  
    default:
      # echo $OS default is to use -g77
      setenv CC       gcc
      setenv CPPFLAGS "-DNDEBUG -Df2cFortran"
      setenv CFLAGS   "-O"
      setenv CXX      ""
      setenv CXXCPP   ""
      setenv FC       g77
      setenv FFLAGS   "-O -Wuninitialized -fno-automatic -ff90-intrinsics-hide"
      setenv F90      ""
      breaksw
  
  endsw

endif

#
# Set MySQL option based on MySQL_ROOT environment variable
#

if ( ${?MySQL_ROOT} ) then
  setenv CFLAGS "-DMySQL_INSTALLED $CFLAGS"
  setenv MYSQL -mysql
  set mysql=`echo $MySQL_ROOT | sed 's/ //g'`
  if ( "$mysql" != "" && "$mysql" != "TRUE" ) then
    setenv MYSQL "-mysql=$mysql"
  endif
else
  unsetenv MYSQL
endif